
 1000  *SAVE S.READ.TIME
 1010  *--------------------------------
 1020  *   READ TIMEMASTER H.O. CARD, PUTTING
 1030  *      TIME INTO APPLESOFT STRING TI$.
 1040  *--------------------------------
 1050  *   ORIGINAL BY JOHN OAKEY, 11-22-85
 1060  *                (c) 1985
 1070  *
 1080  *   MODIFIED BY BOB SANDER-CEDERLOF
 1090  *--------------------------------
 1100  FORPNT .EQ $85,86
 1110  TXTPTR .EQ $B8,B9
 1120  *--------------------------------
 1130  WBUF   .EQ $200
 1140  *--------------------------------
 1150  SLOT   .EQ 5      <<<BE SURE TO PUT YOUR SLOT HERE>>>
 1160  *--------------------------------
 1170  AS.GDBUFS  .EQ $D539     MARK END, CLEAR HI-BITS
 1180  AS.SAVD    .EQ $DA9A     FINISH INSTALLING STRING
 1190  AS.PTRGET  .EQ $DFE3     PARSE STRING NAME
 1200  AS.STRLIT  .EQ $E3E7     BUILD STRING DESCRIPTOR
 1210  *--------------------------------
 1220         .OR $300     (WHERE ELSE!)
 1230  *--------------------------------
 1240  RDTIME LDA TXTPTR   SAVE CURRENT TEXT PNTR
 1250         PHA
 1260         LDA TXTPTR+1
 1270         PHA
 1280  *---READ TIME INTO BUFFER--------
 1290         LDA #"%"     MODE: "FRI JAN 03 10:11:32 AM"
 1300         JSR SLOT*256+$C00B
 1310         JSR SLOT*256+$C008  READ TIME STRING
 1320  *---PREPARE STRING FOR A/S-------
 1330         LDX #23      LENGTH OF STRING
 1340         JSR AS.GDBUFS     CLEAR HI-BITS AND MARK END
 1350  *---SETUP TI$ VARIABLE-----------
 1360         LDA #VARNAM
 1370         STA TXTPTR
 1380         LDA /VARNAM
 1390         STA TXTPTR+1
 1400         JSR AS.PTRGET
 1410         STA FORPNT
 1420         STY FORPNT+1
 1430  *---MOVE TIME INTO TI$-----------
 1440         LDA #WBUF+1  SKIP OVER LEADING QUOTE
 1450         LDY /WBUF+1
 1460         JSR AS.STRLIT
 1470         JSR AS.SAVD
 1480  *---RESTORE TXTPTR, RETURN-------
 1490         PLA
 1500         STA TXTPTR+1
 1510         PLA
 1520         STA TXTPTR
 1530         RTS
 1540  *--------------------------------
 1550  VARNAM .AS /TI$/

